• • Aprender a utilizar el controlador de motores L298N.
  • Comprobar las conexiones Arduino-L298N-motores.
  • Comprobar que los motores giran como esperamos.[/three-fourth]

 

	Tienda España	Tienda Mexico
	Robot educativo	Robot educativo

 

 

En la sesión anterior ya conectamos y explicamos cómo funciona el controlador, pero vamos a recordarlo un poco por encima antes de ponernos a programar.

Para controlar la velocidad de giro de los motores se utilizan los pines ENA y ENB, que hemos conectado a las salidas analógicas 6 y 5 de Arduino respectivamente.

Para controlar el sentido de giro de los motores se utilizan los pines IN1 e IN2, para el motor A y los pines IN3 e IN4 para el motor B, y funcionan de la siguiente forma.

• Si IN1 está a HIGH e IN2 a LOW, el motor A gira en un sentido
• Si IN1 está a LOW e IN2 a HIGH lo hace en el otro.
• Lo mismo con los pines IN3 e IN4 y el motor B.

 

 

Sabemos que con los pines IN1 a IN4 controlamos el sentido de giro de los motores, pero el problema que se nos presenta es que no tenemos forma de saber hacia qué dirección va a girar, así que lo haremos mediante ensayo y error.

Haremos un pequeño programa en el que iremos mandando instrucciones por el puerto serie para controlar el movimiento de los motores.

Lo primero que vamos a necesitar es declarar las variables que utilizaremos para definir los pines que vamos a utilizar y fijar la velocidad fácilmente. Y en el definimos todos como salidas.

// Motor A
int ENA = 6;
int IN1 = 13;
int IN2 = 12;

// Motor B
int ENB = 5;
int IN3 = 11;
int IN4 = 10;

int vel = 200;

void setup()
{
 Serial.begin(9600) ;
 // Declaramos todos los pines como salidas
 pinMode (ENA, OUTPUT);
 pinMode (ENB, OUTPUT);
 pinMode (IN1, OUTPUT);
 pinMode (IN2, OUTPUT);
 pinMode (IN3, OUTPUT);
 pinMode (IN4, OUTPUT);
}

Ahora vamos a suponer que el coche se va a mover hacia delante cuando tengamos IN1 (pin 13 de Arduino) a LOW, IN2 (pin 12) a HIGH, IN3 (pin 11) a LOW e IN4 (pin 10) a HIGH. Además le indicaremos la velocidad a lo que lo tiene que hacer con los pines ENA y ENB.

En el loop vamos a crear una estructura case que utilizaremos para controlar el movimiento, y en función de lo que recibamos por el puerto serie se moverán los motores en una u otra dirección. Utilizaremos ‘F’ para ir hacia delante, ‘B’ para ir hacia atrás, ‘R’ y ‘L’ para girar y ‘S’ para parar.

• Por si alguno no cae, son las inciales de Forward, Backward, Right, Left y Stop.

void loop()
{
 // Motor gira en un sentido
 if (Serial.available())
 switch (Serial.read())
 {
 case 'F':
 Adelante();
 break;
 case 'B':
 Atras();
 break;
 case 'R':
 Derecha();
 break;
 case 'L':
 Izquierda();
 break;
 case 'S':
 Parar();
 break;
 }
}

Y haremos que lo haga cuando reciba una ‘F’ de forward por el puerto serie.

void Adelante ()
{
 //Direccion motor A
 digitalWrite (IN1, LOW);
 digitalWrite (IN2, HIGH);
 analogWrite (ENA, vel); //Velocidad motor A
 //Direccion motor B
 digitalWrite (IN3, LOW);
 digitalWrite (IN4, HIGH);
 analogWrite (ENB, vel); //Velocidad motor B
}

Para comprobarlo encendemos el interruptor del coche y pulsamos la tecla hacia delante. Pueden pasar 4 cosas:

• Que el coche se mueva hacia delante. ¡Perfecto! Hemos tenido suerte y no vamos a tener que cambiar nada.
• Que el coche se mueva hacia detrás. Los dos se mueven al revés de lo que hemos supuesto.
• Que el coche gire hacia la derecha. El motor B gira al revés de lo que hemos supuesto.
• Que el coche gire a la izquierda. El motor A gira al revés de lo que hemos supuesto.

Bueno, pues si sois de la primera opción, felicidades, y sino no pasa nada porque esto tiene fácil arreglo, y de hecho, podemos arreglarlo de varias formas.

Podemos intercambiar las dos conexiones del motor que esté girando al revés de lo que buscamos, o de los dos motores si los dos lo hacen al revés. OUT1 y OUT2 para el motor A, y OUT3 y OUT4 para el motor B.

Si os resulta complicado acceder a esos cables, también podéis intercambiar los pines que controlan el sentido de giro de los motores. Es decir, IN1 e IN2 para el motor A, e IN3 e IN4 para el motor B.

Y si no queréis andar cambiando los cables podemos cambiar el programa. Sólo tendríamos que cambiar el estado de los pines que dan el sentido de giro del motor que queramos invertir. Si, por ejemplo, quisiéramos cambiar el sentido de giro del motor A, haríamos lo siguiente:

void Adelante ()
{
 //Direccion motor A
 digitalWrite (IN1, LOW);
 digitalWrite (IN2, HIGH);
 analogWrite (ENA, vel); //Velocidad motor A
 //Direccion motor B
 digitalWrite (IN3, HIGH);
 digitalWrite (IN4, LOW);
 analogWrite (ENB, vel); //Velocidad motor B
}

¡Accede al contenido!

Si lo corregís de cualquiera de las dos primeras formas, el resto del programa podéis seguirlo igual que el que vayamos haciendo nosotros. Si lo hacéis de la última forma, tendréis que tenerlo en cuenta también para el resto del programa y cambiarlo también para los demás movimientos.

 

 

Una vez que tenemos programado el movimiento hacia delante y tenemos claro cómo giran nuestros motores, el resto lo tenemos fácil. Ahora vamos a hacer que se mueva hacia atrás al recibir ‘B’ (de Backward), para lo que sólo necesitaremos invertir los pines 10 al 13 que controlan el sentido de giro.

void Atras ()
{
 //Direccion motor A
 digitalWrite (IN1, HIGH);
 digitalWrite (IN2, LOW);
 analogWrite (ENA, vel); //Velocidad motor A
 //Direccion motor B
 digitalWrite (IN3, HIGH);
 digitalWrite (IN4, LOW);
 analogWrite (ENB, vel); //Velocidad motor B
}

Si lo que queremos es girar a la derecha, el motor A debería ir hacia delante y el B hacia atrás, y lo contrario para girar a la izquierda. Como podréis imaginar utilizaremos ‘R’ y ‘L’ (Right y Left)

void Derecha ()
{
 //Direccion motor A
 digitalWrite (IN1, LOW);
 digitalWrite (IN2, HIGH);
 analogWrite (ENA, vel); //Velocidad motor A
 //Direccion motor B
 digitalWrite (IN3, HIGH);
 digitalWrite (IN4, LOW);
 analogWrite (ENB, vel); //Velocidad motor A
}

void Izquierda ()
{
 //Direccion motor A
 digitalWrite (IN1, HIGH);
 digitalWrite (IN2, LOW);
 analogWrite (ENA, vel); //Velocidad motor A
 //Direccion motor B
 digitalWrite (IN3, LOW);
 digitalWrite (IN4, HIGH);
 analogWrite (ENB, vel); //Velocidad motor A
}

Y por último haremos que los motores se paren al recibir ‘S’ (de Stop).

void Parar ()
{
 //Direccion motor A
 digitalWrite (IN1, LOW);
 digitalWrite (IN2, LOW);
 analogWrite (ENA, 0); //Velocidad motor A
 //Direccion motor B
 digitalWrite (IN3, LOW);
 digitalWrite (IN4, LOW);
 analogWrite (ENB, 0); //Velocidad motor A
}

Podéis descargar el programa completo aquí: prueba_motores_l298n.

¡Accede al contenido!

 

 

En esta sesión hemos aprendido varias cosas importantes:

• Cómo controla el L298N con un Arduino.
• A programar correctamente el movimiento de los motores del coche.