Conectar un módulo ESP8266 a una red WiFi.

Conectarle un sensor DHT11 y leer los datos de temperatura y humedad.

Aprender a subir los datos a un servidor.[/three-fourth] [clear/]

 

 

	Nodemcu V2
	Sensor DHT11

 

 

Antes de comenzar esta sesión vamos a repasar algunas cosillas que vamos a necesitar tener preparadas, y otras que tenemos que considerar ante de ponernos a realizarla.

Lo primero es bastante evidente, si vamos a querer subir valores a una base de datos que tengamos en un servidor, necesitamos un servidor preparado para ello. Podéis haceros uno propio, o utilizar alguna página que lo permite, como https://thingspeak.com/.

Nosotros vamos a aprovechar que montamos un servidor utilizado una Raspberry y vamos a subir los valores a la tabla que creamos en una base de datos SQL. Si no le habéis echado un ojo antes, aquí os dejamos los enlaces:

Crear un servidor en la Raspberry Pi

Abrir el servidor a Internet

 

Por otra parte, si estáis familiarizados con los esp8266, sabréis que hay bastantes modelos diferentes con ese mismo chip. Aquí hace tiempo que nos decidimos por los NodeMCU (a partir del modelo 1.0), que son a nuestro parecer los más sencillos y completos, así que este tutorial vamos a hacerlo utilizando uno de ellos. Si no habéis trabajado nunca con este tipo de módulos, tenemos algunas sesiones en las que hablamos de todo esto más en profundidad:

Índice de tutoriales ESP8266

Modelos del ESP8266

Programando NODEMCU con Arduino IDE

Los nuevos modelos de ESP8266.[/fancy-ul] [/three-fourth]

 

 

El DHT11 es un sensor que nos permite leer la temperatura y la humedad relativa. No es muy preciso, pero es muy barato y fácil de utilizar, y nos va a servir de sobra para lo que queremos hacer. Estos sensores se presentan de muy diversas formas, con 3 o 4 pines en función de si tienen la resistencia pull-up incluida o no, y el orden de los pines puede variar de un modelo a otro, así que es importante que os fijéis en el vuestro. Los más normales son estos dos:

Una vez tengamos claro cuál es el nuestro sólo tenemos que conectarlo. En este caso el nuestro tiene la resistencia pull-up incorporada y 3 pines, así que la conexión la haríamos de esta forma (si tenéis el de 4 pines y no sabéis cómo conectarlo, podéis echar un ojo aquí)

Ahora ya podemos empezar con el programa, pero antes tendremos que descargar el pluggin para el esp8266 si no lo habéis usado nunca anteriormente. Aquí tenéis una sesión en la que indicamos como hacerlo Instalar el pluggin ESP8266 en Arduino.

Una vez instalado el pluggin lo primero que deberíais  hacer es descargar la librería que vamos a utilizar DHT11.zip si no la habéis usado nunca antes. Comenzamos el programa incluyendo la librería y  definimos una instancia del sensor donde declaramos el pin al que esta conectado.

#include <DHT11.h>
DHT11 dht11(D4);

Si os fijáis, hemos nombrado el pin como D4, y no como 4 como haríamos con cualquier Arduino normal. Y es que los nombres de los pines no corresponden con los GPIOS en el NodeMCU. De hecho si probáis a poner 4, no funcionará, ya que el pin que identifica como 4 es el rotulado como D2. En está imagen lo podréis ver de forma más clara:

Así que para evitar confusiones podéis poner la ‘D’ por delante y él pluggin se encargará hará de hacer la relación.

Por lo demás el programa es sencillo. Utilizaremos la función dht11.read pasándole como parámetros las variables donde queremos guardar los valores, comprobando que no haya un error . El programa quedaría así:

#include <DHT11.h>

int pin=2;
DHT11 dht11(pin);

void setup()
   {
       Serial.begin(9600);
   }

void loop()
   {
       int err;
       float temp, hum;
       if((err = dht11.read(hum, temp)) == 0)    // Si devuelve 0 es que ha leido bien
          {
             Serial.print("Temperatura: ");
             Serial.print(temp);
             Serial.print(" Humedad: ");
             Serial.print(hum);
             Serial.println();
          }
       else
          {
             Serial.println();
             Serial.print("Error Num :");
             Serial.print(err);
             Serial.println();
          }
       delay(1000);            //Recordad que solo lee una vez por segundo
   }

Ahora probad a subir el programa, asegurándoos de que habéis seleccionado como placa el NodeMCU. Una vez cargado, si abrimos el puerto serie veremos los valores de temperatura y humedad.

Podéis hacer que suban tanto la temperatura como la humedad echando un poco de aliento en el sensor, y veréis cómo varían los valores.

 

 

 

Ya sólo nos queda subir los valores al servidor.Básicamente lo que hemos hecho ha sido adaptar uno de los programas que vienen de ejemplo con la librería llamado «WiFiClient». Lo primero que hacemos es incluir la librería (no tenéis que descargarla porque se instala con el pluggin que ya hemos descargado), y además vamos a declarar algunas variables que usaremos para conectarnos a la red WiFi, nombre de la red y password, y la dirección del servidor al que subiremos los datos.

#include <DHT11.h>
#include <ESP8266WiFi.h>

DHT11 dht11(D4);

const char* ssid = "Euskaltel-cs7A";
const char* password = "xxxxxxxx";

const char* host = "prometecserver.ddns.net";

En el setup establecemos la conexión con la red WiFi y mostramos por el puerto serie la dirección IP que nos ha asignado.

void setup()
{
 Serial.begin(9600);
 // We start by connecting to a WiFi network

 Serial.println();
 Serial.println();
 Serial.print("Connecting to ");
 Serial.println(ssid);

 WiFi.begin(ssid, password);

 while (WiFi.status() != WL_CONNECTED) {
 delay(500);
 Serial.print(".");
 }

 Serial.println("");
 Serial.println("WiFi connected");
 Serial.println("IP address: ");
 Serial.println(WiFi.localIP());
}

Y ya en loop lo primero que haremos será obtener los datos de temperatura y humedad de las misma forma que en el apartado anterior. Una vez los tenemos vamos a utilizar la clase WiFIClient para establecer una conexión TCP. Para ello tenemos que declarar una serie de Strings a partir de las cuales montaremos la URL completa a la que nos vamos a conectar.

El símbolo «?» indica que empieza el envío de parámetros al servidor.

Después del símbolo «?» enviamos los parámetros identificándolos con su nombre y fijando su valor separados por el símbolo «&».

En nuestro caso los parámetros son la contraseña «pass» y los datos del sensor «Temperatura» y «Humedad».

Existen dos formas de enviar los datos a la página, mediante GET o POST. Ambos envían una petición y reciben una respuesta aunque de una forma un poco diferente, y ambos funcionarían en el programa (podéis buscar información de sus diferencias fácilmente).

 

Ahora ya podemos enviar la petición al servidor:

 Serial.print("connecting to ");
 Serial.println(host);

 // Use WiFiClient class to create TCP connections
 WiFiClient client;
 const int httpPort = 80;
 if (!client.connect(host, httpPort)) {
 Serial.println("connection failed");
 return;
 }

 // We now create a URL for the request
 String url = "/dht11.php";
 String key = "?pass=1234";
 String dato1 = "&Temperatura=";
 String dato2 = "&Humedad=";

 Serial.print("Requesting URL: ");
 Serial.println(url);

 // This will send the request to the server
 client.print(String("GET ") + url + key + dato1 + temp + dato2 + hum + " HTTP/1.1\r\n" +
 "Host: " + host + "\r\n" +
 "Connection: close\r\n\r\n");
 unsigned long timeout = millis();
 while (client.available() == 0) {
 if (millis() - timeout > 5000) {
 Serial.println(">>> Client Timeout !");
 client.stop();
 return;
 }
 }

Y ya por último leemos la respuesta del servidor y cerramos la conexión. Además le vamos a poner un delay para que suba los datos cada 60 segundos. Vosotros podéis adaptar el tiempo al que mejor os parezca.

  // Read all the lines of the reply from server and print them to Serial
 while (client.available()) {
 String line = client.readStringUntil('\r');
 Serial.print(line);
 }

 Serial.println();
 Serial.println("closing connection");

 delay(60000);

Aquí os dejamos el programa completo: Esp8266_DHT11_Cliente.

¡Accede al contenido!

Ahora no tenéis más que subir el programa y si abrís el puerto serie veréis como establece la conexión a la red WiFi y envía una petición cada minuto.

Y si ahora accedéis al servidor al que lo habéis subido y miráis en la base de datos deberían estar esos mismos valores en la tabla a la que los hayáis subido, en nuestro caso el de la Raspberry que gestionamos con phpMyAdmin.

Con esto creemos ya estaréis en posición de adaptar este programa para vuestros propios montajes y propósitos. Estaremos encantados de que nos hagáis llegar vuestros proyectos. Nosotros os dejamos por aquí un vídeo con el resultado:

 

 

En esta sesión hemos aprendido varias cosas importantes:

Hemos usado un DHT11 para leer los datos de temperatura  humedad usando un NodeMcu.

Nos hemos conectado a una red WiFi.

A establecer una conexión TCP con un servidor.

Hemos subido los datos de temperatua y humedad a un servidor.[/three-fourth][margin value=»5″ /]