Objetivos
Material requerido.
 |
Kit inicio UNO |
 |
Kit Inicio Mega |
Volviendo con los Motores paso a paso
En la sesión anterior dimos un pequeño repaso a la teoría que hay detrás de los motores paso a paso e intentamos sentar las cuatro ideas importantes que debéis conocer para elegir y usar con éxito, uno de esto motores.
En esta sesión, vamos a usar un pequeño motor paso a paso unipolar, muy común en el mundo Arduino por su pequeño tamaño y bajo coste, el 28BYJ-48 y el adaptador que suele venir con él, basado en el chip ULN2003A.
Veremos en primer lugar las características que presenta y después montaremos un pequeño circuito básico, para mover el motor. Como siempre intentaremos que el ejemplo sea lo más simple posible para que en esta primera ocasión veáis con claridad la forma de manejarlos.
Y poco más que decir en esta pequeña introducción. Vamos pues, a meternos directamente en harina.
El motor paso a paso 28BYJ-48
Este pequeño motor es muy habitual en los proyectos con pequeños robots y posicionadores caseros sencillos, porque aunque no es demasiado potente, ni rápido tiene varias características más que simpáticas, además de ser muy barato (Unos pocos euros).
Y como no podía ser de otra manera, empezaremos por buscar su manual (Va que sí, que vosotros podéis encontrarlo en Internet).
Es un motorcito unipolar con las siguientes características:
- Tensión nominal de entre 5V y 12 V.
- 4 Fases.
- Resistencia 50 Ω.
- Par motor de 34 Newton / metro más o menos 0,34 Kg por cm.
- Consumo de unos 55 mA.
- 8 pasos por vuelta.
- Reductora de 1 / 64.
Traduciendo esto a cristiano, quiere decir que como es de 4 pasos (Steps), u 8 medios pasos (O half Steps) por vuelta y usa una reductora de 1 /64, por lo que necesitamos dar 8 * 64 = 512 impulsos para completar un giro completo a medios pasos.
- Sé que parece confuso. Hay 4 bobinas, si las excitamos de una en una tenemos 4 pasos x 64=256 pasos por vuelta. Pero también podemos excitar la bobina mediante medios pasos, como veíamos en las tablas de la sesión previa (que es el ejemplo que vamos a hacer) y por eso a medios pasos una vuelta son 8 * 64 = 512 impulsos
Además si no recuerdo mal de mis lejanos días de universidad, un par de 0,34 Kg por cm, significa que con una polea de un 1cm de diámetro colocado en el eje, este pequeño motor levantaría un peso de 350 gramos contra la gravedad, lo que no está mal.
Este es su diagrama de conexión de bobinas, y además marca los colores del cable en función de su conexión interna. El motor presenta un conector al extremo en el que podemos pinchar cables de protoboard si hay que moverlo directamente, o bien para conectarlo a su adaptador.
Fijaros que su consumo es muy bajo, de unos 55 mA, dentro del rango que nuestro USB proporciona a Arduino (Siempre que no intentemos alimentarlo con un pin) y lo alimentaremos mediante la breakboard típica que le acompaña, que suele usar un integrado del tipo ULN2003A que es un array de transistores Darlington, que soporta hasta 500 mA y que ya dispone de un conector para el motor y de unos pines (IN1 – IN4) para conectar a nuestro Arduino.
- Sin entrar en muchos detalles, un Darlington suele ser un par de transistores bipolares colocados juntos y que se manejan como uno único.
- La ventaja de este esquema es que aumenta mucho la ganancia del transistor resultante y además permite la conducción de grandes corrientes y tensiones.
- Hemos usado uno de estos transistores para alimentar una tira Ed LEDS aquí.
Conectando el motor 28BYJ-48
Pues usando la breakboard no tiene mucho mérito. Conectad el motor primero a su conector, que tiene una posición para impedir que lo coloques al revés y después vamos a colocar las 4 fases a nuestro Arduino de modo que podamos excitarlas de forma independiente.
Es importante que entendáis la idea de que vamos a ir excitando cada una de las fases (O varias simultáneamente) en secuencia levantando a HIGH el pin de Arduino correspondiente.
No merece la pena montar un esquema de protoboard para esto. Para conectar vuestro Arduino usad la siguiente tabla:
| Arduino | 12 | 11 | 10 | 9 |
|---|---|---|---|---|
| Breakout | IN1 | IN2 | IN3 | IN4 |
Conectad GND y Vcc a los pines correspondientes del adaptador y eso es todo (Gran ventaja cuando usas módulos a medida) vamos con el programa.
El programa de control
Mientras que los motores CC normales, están diseñados para que al alimentarlos giren de forma continua, un motor paso a paso está diseñado para girar un pasito cada vez que alimentas una de las fases.
Por eso nuestro programa tendrá que gestionar la secuencia en la que excitamos las bobinas para que el motor vaya avanzando de forma continua.
En un motor de 4 fases como este que vamos a usar hay tres maneras de hacer esta secuencia como veíamos en la sesión anterior.
Excitando dos bobinas cada vez (Suele ser lo que recomienda el fabricante)
| PASO | Bobina A | Bobina B | Bobina C | Bobina D | |
|---|---|---|---|---|---|
| 1 | ON | ON | OFF | OFF |  |
| 2 | OFF | ON | ON | OFF | |
| 3 | OFF | OFF | ON | ON | |
| 4 | ON | OFF | OFF | ON |
Tendríamos máximo par, buena velocidad y alto consumo.
Excitando solo una bobina cada vez (Se le llama wave drive):
| PASO | Bobina A | Bobina B | Bobina C | Bobina D | |
|---|---|---|---|---|---|
| 1 | ON | OFF | OFF | OFF |  |
| 2 | OFF | ON | OFF | OFF | |
| 3 | OFF | OFF | ON | OFF | |
| 4 | OFF | OFF | OFF | ON |
Que produciría un par menor (Porque solo se activa una bobina en lugar de dos) y consumo bajo.
O podríamos dar medios pasos así:
| PASO | Bobina A | Bobina B | Bobina C | Bobina D | |
|---|---|---|---|---|---|
| 1 | ON | OFF | OFF | OFF |  |
| 2 | ON | ON | OFF | OFF | |
| 3 | OFF | ON | OFF | OFF | |
| 4 | OFF | ON | ON | OFF | |
| 5 | OFF | OFF | ON | OFF | |
| 6 | OFF | OFF | ON | ON | |
| 7 | OFF | OFF | OFF | ON | |
| 8 | ON | OFF | OFF | ON |
El movimiento es más suave y lento que con los métodos anteriores, y el consumo y el par es también intermedio.
Y naturalmente lo habituales, ya os habréis sospechado que vamos a definir unos arrays con estas tablas para secuenciar el movimiento. Por ejemplo en el caso de usar medios pasos el array sería algo así:
int Paso [ 8 ][ 4 ] =
{ {1, 0, 0, 0},
{1, 1, 0, 0},
{0, 1, 0, 0},
{0, 1, 1, 0},
{0, 0, 1, 0},
{0, 0, 1, 1},
{0, 0, 0, 1},
{1, 0, 0, 1}
};
Y seguro que no tendréis problema en definir el array correspondiente a los otros dos tipos de movimiento
Nuestro programa recorrerá el array y alimentara las bobinas de acuerdo a los valores que presenta. Puedes descargarlo aquí:
Empecemos con algunas definiciones:
#define IN1 12 #define IN2 11 #define IN3 10 #define IN4 9 int steps_left=4095; boolean Direction = true; int Steps = 0; // Define el paso actual de la secuencia
Los defines indican a que pines de nuestro Arduino vamos a conectar cada una de los terminales de las bobinas del motor. Después algunas variables para control y un array que representa la secuencia. El setup es bastante sencillo
void setup()
{ pinMode(IN1, OUTPUT);
pinMode(IN2, OUTPUT);
pinMode(IN3, OUTPUT);
pinMode(IN4, OUTPUT);
}
Vamos a definir una función llamada stepper() que avanza un paso cada vez que la invocamos, en realidad medio paso dada la matriz de excitación y que controle en que punto de la secuencia estamos.
Así, el programa principal quedaría: Prog_98_1
void loop()
{ while(steps_left>0)
{
stepper() ; // Avanza un paso
steps_left-- ; // Un paso menos
delay (1) ;
}
delay(300);
Direction =! Direction; // Invertimos la direceccion de giro
steps_left = 4095;
}
Usamos Steps_left para definir el número de pasos que queremos girar, y por eso mientras queden pasos pendientes seguimos en el while, que lo que hace es avanzar un paso, disminuir el número de pasos pendientes y hacer un delay que controla la velocidad de giro.
Cuando acaba el while, hacemos un delay para poder apreciar el final e invertimos el valor de direction para cambiar la dirección de giro.Vamos con la funcion Stepper que parece más complicada:
void stepper() //Avanza un paso
{ digitalWrite( IN1, Paso[Steps][ 0] );
digitalWrite( IN2, Paso[Steps][ 1] );
digitalWrite( IN3, Paso[Steps][ 2] );
digitalWrite( IN4, Paso[Steps][ 3] );
SetDirection();
}
Lo se, da asco. Es tan fácil que aburre. Usamos la variable Steps para saber en cuál de los 8 estados posibles de la matriz estamos y escribimos en las bobinas los valores que corresponden a esa situación.
Es SetDirection() quien va a controlar la dirección de giro y el valor de Steps, vamos a ver como:
void SetDirection()
{
if(Direction)
Steps++;
else
Steps--;
Steps = ( Steps + 8 ) % 8 ;
}
Es muy fácil ver que si giramos en la dirección digamos positiva, hay que ir incrementando Steps para mantener el giro. Y tampoco es complicado ver que en el giro contrario hay que irlo decrementando para que lea el array al revés. Pero quizás la última línea merece una explicación aparte.
A medida que vamos incrementando Steps, queremos que cuando pase de 7 vuelva a 0 y esto se consigue muy fácil haciendo
Steps = Steps % 8
Es decir tomando el modulo con respecto a 8, pero si lo vamos decrementando, alcanzaremos valores negativos, y el módulo de algo negativo sigue siendo negativo, lo que no nos vale, porque necesitamos que el siguiente valor a 0 sea 7 y no -1.
Esto es lo que conseguimos de una tacada haciendo
Steps = ( Steps + 8 ) % 8 ;
Compruébalo si no me crees.
- He visto en Internet que esto lo hacen con un programita así:
if (Steps>7) Steps=0 ; if (Steps<0) Steps=7 ; - Pero mi sentido de la estética y la vagancia me impiden escribir tanto y además son completamente equivalentes (Y además es un código mas compacto y quedón el primero)
El resultado es un motorcito girando primero en una dirección y después en la contraria tranquilamente.
Resumen de la sesión
<